BlobbieScript - Expressions

Previously the Easyact engine supported some simple block control mechanisms. Some of the mechanisms worked well, others not so well. The 'if' statement is a good example for one that generally works well. One of the greatest drawbacks of the 'if' statement though, is its lack of support for joining conditional expressions. This is solved in the new engine. The following control blocks are supported by BlobbieScript:

Keyword	Description
static	Initialize static variables
if	Test for conditional block entry
elseif	Test for conditional block entry where priors have failed
else	When all prior tests fail then enter this block
endif	Close a series of conditionals
for	Initialize and loop over some expression while it evaluates to true.
endfor	Loop back to beginning of the matching for block.
foreach	Iterate over an array's values.
endforeach	Loop back to beginning of the matching foreach block.
do	Enter a looping block
dowhile	Test conditional for re-entry into 'do' block
while	Test conditional for entry into block
endwhile	Loop back to beginning of a 'while' conditional loop
switch	Select the first matching case and continue evaluation from that point.
case	A conditional starting point based on the case value matching the switch value.
default	If all case statements for the switch block fail, then evaluation will continue at the default statement.
endswitch	Marker for the end of a switch block.
wait	Wait for a number of time units (secs, hsecs, qsecs, tsecs)
protect	Run code in block to completion
endprotect	Marker for end of protected block
break	Break out of innermost loop or switch statement; if none then return
continue	Jump to beginning of looping block immediately
label	Set a marker for a 'jumpto' statement
jumpto	Jumpto a given labelled point in the script
return	Exit script optionally providing a return value
retval	Return a value but do not exit script
null	The special null value / datatype.
true	Boolean true value.
false	Boolean false value.
<<	The final evaluation of the whole line is fed into the mud's interpreter as though the script owner had issued it as a command.
\	Indicates line continues or is a continuation
{ or }	A line containing only these and spaces is ignored

Expression Evaluation

One of the biggest problems in creating the BlobbieScript engine was to try and add in real language support while adding the flexibility of evaluating expressions as can be done in almost any other programming language. To maximize ease and backward compatibility there exist two modes of expression evaluation: pure and impure.

Pure expressions are any expressions that are part of a block control expression or part of a function's parameter part. These are called pure because they do not require special treatment to be evaluated in their context. To illustrate, the following is now possible:

if( %getLevel( $n ) < 50 and !%getRandom( 1, 10 ) )
{
   damage $n %( (1d10 + 1) * 3 )
}
else-
if( %getAlign( $n ) / 10 > 60 or %getAlign( $n ) < -60 )
{
   damage $n %( 1d(1d10) )
}
endif

The difference between pure and impure expressions is also illustrated above. Notice to get the power of expression evaluation within a non- block control statement the expression needs to be evaluated with the special %() function. This is because for backward compatibility reasons the new engine guesses that anything in a block control statement is any of variable, function, or string. Given this interpretation all tokens extracted are considered to be implicitly joined by an invisible concatenation operator. Since this may become confusing if a variable is used that blends into an actual word the following can be used to ensure the end of the variable:

0001 @name = %getName( $n )

0002 echoto r all @{name}'s mother is a wench!

The advantage of such expression evaluation is that it gets rid of the old system of $.calc( 1, +, 3 ) since this can be expressed as %( 1 + 3 ). Moreover the engine fully supports integers, floats, strings, and associative arrays (AKA: dictionary, string indexed array, hash).

Other Types of Expressions

In addition to block control expressions and normal expressions there are comments, continuations, and block tags. Comments begin when a pair of forward slashes "//" are encountered and end at the end of the line.

Example:

//
// Get a list of creatures in the room.
//
@list = %roomGetMobs()     // Creatures are stored in @list

*
* This is a deprecated style, and only works when
* the "*" is the first non-whitespace character on
* a line.
*

The \ at the beginning of a line denotes that the expression continues from the previous line. This was added so conditionals can be nicely formatted for easy reading.

Example:

echoto room all
\   You can feel the rush of winds building in strength to
\   a deafening roar. You clasp your ears to mitigate the
\   painful effects of the sound.

Block control tags are more for aesthetic purposes. I come from programming background which uses braces to denote code blocks. Normally BlobbieScript doesn't support these blocks due to backwards compatibility; however, for the sake of good looking code (IMHO) any line containing only a sequence of "{" or "}" characters will be ignored.

Example:

if( @n->name == "The Overlord" )
{
   echoto notc @n Grovel before your master heathens!
}
else
{{{{
   spit @n
}}}}
endif

Finally a semi-colon is permitted on most pure expressions where one would make sense. The behaviour of the engine is to strip it if it is the last character on the line. Note that commands normally passed on to the game's command interpreter will retain any trailing semi-colons.

Example:

@i = 20;
while( (@i -= 1) > 0 )
{
   echoto room all A fireball suddenly explodes before you.
   damage room all %( 20 + 1d15 ) fire

   wait 20 secs;
}
endwhile;


	The Worlds of Carnage MUD is a non-profit, fantasy oriented, text-based game that is played over telnet. We are devoted to providing a social medium in which people can have fun while immersing themselves in a game that reads like a book. You can connect by clicking here or if that fails then here. This site is maintained and hosted by Robert Cummings, A.K.A Blobule. The Worlds of Carnage are often recognized via the following aliases: Carnage; WoC; WoC MUD; Carnage MUD; CarnageMUD; WoCMUD. All submissions become the property of Robert Cummings where the submitter holds copyright. If you do not want to give ownership, then do not submit.